5.2. Wat is het aantal cliënten per financieringsstroom?

Concepten

• Forensische indicatiestelling
• Indicatiebesluit
• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• Wmo-indicatie
• Zorgkantoor regio
• Zvw-indicatie

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 5.2
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9
10SELECT ?Periode
11  (?vestiging AS ?Indeling)
12  (IF(?vestiging = "Totaal organisatie", "", SAMPLE(?zk_regio_code)) AS ?Zorgkantoorregio_code)
13  (COUNT(DISTINCT IF(BOUND(?wlz), ?client, ?unbound)) AS ?Wlz)
14  (COUNT(DISTINCT IF(BOUND(?zvw), ?client, ?unbound)) AS ?Zvw)
15(COUNT(DISTINCT IF(BOUND(?wmo), ?client, ?unbound)) AS ?Wmo)
16  (COUNT(DISTINCT IF(!BOUND(?zvw) && !BOUND(?wlz) && !BOUND(?wmo), ?client, ?unbound)) AS ?Overig)
17WHERE {
18  #BIND(2024 AS ?jaar)
19  VALUES ?kw {
20    1 2 3 4 0
21  }
22
23  BIND(
24    xsd:date(CONCAT(STR(?jaar), "-",
25      IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
26    ))
27    AS ?peildatum_eerder
28  )
29  BIND(
30    xsd:date(CONCAT(STR(?jaar), "-",
31      IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
32    ))
33    AS ?peildatum_later
34  )
35  BIND(IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode)
36
37  {
38    ?indicatie a onz-zorg:IndicatieBesluit
39  } UNION {
40    ?indicatie a onz-zorg:ForensischeIndicatieStelling
41  }
42
43  ?indicatie onz-g:isAbout ?client .
44  ?client a onz-g:Human .
45
46  ?indicatie ^onz-g:definedBy ?zorgproces ;
47    onz-g:startDatum ?start_ind .
48  OPTIONAL {
49    ?indicatie onz-g:eindDatum ?eind_ind .
50  }  
51    # Filter ook indicatie op datum
52    FILTER (
53    ?start_ind <= ?peildatum_later &&
54    (!BOUND(?eind_ind) || ?eind_ind >= ?peildatum_eerder)
55  )
56  ?zorgproces
57    onz-g:hasPerdurantLocation ?locatie ;
58    onz-g:startDatum ?start_zorgproces .
59  OPTIONAL {
60    ?zorgproces onz-g:eindDatum ?eind_zorgproces .
61  }
62
63  FILTER (
64    ?start_zorgproces <= ?peildatum_later &&
65    (!BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?peildatum_eerder)
66  )
67
68  OPTIONAL {
69    ?indicatie a onz-zorg:WlzIndicatie .
70    BIND(1 AS ?wlz) .
71  }
72  OPTIONAL {
73    ?indicatie a onz-zorg:ZvwIndicatie .
74    BIND(1 AS ?zvw) .
75  }
76  OPTIONAL {
77    ?indicatie a onz-zorg:WmoIndicatie .
78    BIND(1 AS ?wmo) .
79  }
80
81  {
82    ?locatie onz-g:partOf* ?vestiging_uri .
83    ?vestiging_uri a onz-org:Vestiging ;
84      onz-g:identifiedBy ?vest_nr ;
85      onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
86    ?vest_nr a onz-org:Vestigingsnummer ;
87      onz-g:hasDataValue ?vestiging .
88
89    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
90    ?pc_gebied onz-g:identifiedBy ?postcode ;
91      onz-g:partOf+ ?zk_regio .
92    ?zk_regio a onz-org:ZorgkantoorRegio .
93  } UNION {
94    ?locatie onz-g:partOf* ?vestiging_uri .
95    ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
96    BIND("Totaal organisatie" AS ?vestiging)
97  }
98
99  BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
100
101
102}
103GROUP BY ?Periode ?vestiging
104ORDER BY ?Periode ?vestiging
105